home *** CD-ROM | disk | FTP | other *** search
/ ShareWare OnLine 2 / ShareWare OnLine Volume 2 (CMS Software)(1993).iso / bbs_soft / mrun210.zip / MRUN210G.WAS < prev    next >
Text File  |  1993-04-27  |  45KB  |  1,671 lines
  1. ;MailRun v2.10:  Part G, domailrun
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #COMMENT
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * The following procedures form the engine of the script.  First
  9. * makedir() is called to create a dialing directory for BBSs listed
  10. * in the *.MRN file that have pending items.  Each BBS is called,
  11. * and on connection, each pending item listed for that BBS is executed
  12. * by dobbs().  These tasks are performed by sendmail(), getmail(),
  13. * ulfile(), dlfile(), and sendcommand().  As each task is completed,
  14. * the task list window is updated.
  15. * 
  16. * While online, the key procedure is holding() which keeps track of the
  17. * length of time the board has been inactive, checks for dropped carrier
  18. * and obtains the current line from the terminal screen so that it can
  19. * be parsed by the various procedures that respond to prompts.  The
  20. * latter include checkbaseset(), checkcommandprompt(), checkmailprompt()
  21. * and the like.
  22. * 
  23. **************************************************************************
  24. **************************************************************************
  25. #ENDCOMMENT
  26.  
  27. #define MRUN210G
  28. #define MRUN210AG
  29.  
  30. #define GOTOFILE 1
  31. #define GOTOMAIN 0
  32.  
  33. string MainBoxTabs, prompt
  34. integer xferstatus, holdstatus, foundstatus
  35.  
  36. #include "mrun210.h"
  37.  
  38.  
  39. #comment
  40. *********************************************************************
  41. * 
  42. * MAIN()
  43. * 
  44. * Calls menudim(), checkchild(), maketasklist(), dobbs()
  45. * mailrunbox(), parsedialog(), makequeue(), readbbs(),
  46. * makefullname(), findstring(), capturescreen()
  47. * 
  48. * Main first calls the initialization routines, then puts
  49. * up the main dialog box and dispatches each requested
  50. * action.
  51. * 
  52. *********************************************************************
  53. #endcomment
  54.  
  55. proc main
  56. string DialString, PhoneNum, ComString, ComMsg, BBSName
  57. string  CnctFail1, CnctFail2, CnctFail3, CnctFail4, CnctFail5
  58. string char
  59. integer ComStringLength
  60. integer Attempts, MaxAttempts, DialOutTime, RingInterrupt
  61. integer i, j, n
  62. integer FirstCall
  63.     menudim()
  64.     checkchild()
  65.     profilerd MailRunIni "MailRun" "MailRunDir" MailRunDir
  66.     TaskList = makefullname(TempDir, "TASKLIST.TMP")
  67.     findfirst MailRun
  68.     MailRunTrunc = $FILENAME
  69.     maketasklist()
  70.     mailrunbox()
  71.     makequeue()
  72.     ;interface is turned on by makequeue
  73.     when dialog call parsedialog
  74.     profilerd MailRun "MailRun" "LogRun" LogRun
  75.     if LogRun
  76.         profilerd MailRun "MailRun" "AnsiInLog" AnsiInLog
  77.         if AnsiInLog
  78.             set capture mode append RAW
  79.         else
  80.             set capture mode append VISUAL
  81.         endif
  82.         capture ON
  83.     endif
  84.     profilerd MailRun "MailRun" "DialAttempts" MaxAttempts
  85.     fetch modem nocnct1 CnctFail1
  86.     fetch modem nocnct2 CnctFail2
  87.     fetch modem nocnct3 CnctFail3
  88.     fetch modem nocnct4 CnctFail4
  89.     fetch modem nocnct5 CnctFail5
  90.     Attempts = 1
  91.     FirstCall = 1
  92.     while Attempts <= MaxAttempts
  93.         itoa Attempts AttemptNum
  94.         updatedlg 64
  95.         ;Keep dialing until the maximum number of attempts has been made
  96.         ;reread MaxAttempts on each loop in case the user changes settings
  97.         profilerd MailRun "MailRun" "DialAttempts" MaxAttempts
  98.         n = 1
  99.         DialString = getdialstring(&n)
  100.         if n == 0
  101.             exitwhile
  102.         endif
  103.         while not NULLSTR DialString
  104.             ;Loop until all numbers have been called
  105.             strextract PhoneNum DialString "`t" 0
  106.             strextract char DialString "`t" 1
  107.             atoi char i
  108.             BBS = readbbs(i)
  109.             profilerd MailRun BBS "BBSName" BBSName
  110.             set aspect rxdata ON
  111.             rxflush
  112.             if FirstCall != 1
  113.                 ;Don't pause if this is the first call in the loop
  114.                 profilerd MailRun "MailRun" "DialPause" j
  115.                 profilerd MailRun "MailRun" "RingInterrupt" RingInterrupt 
  116.                 while j > 0
  117.                     statmsg "Last Message:  %s      Pausing  %d" ComMsg j
  118.                     pause 1
  119.                     j--
  120.                     ComStringLength = $RXCOUNT
  121.                     comgets ComString ComStringLength
  122.                     if RingInterrupt && findstring(ComString, "RING")
  123.                         capturescreen()
  124.                         capturestr \
  125.                             "`r`n`r`n**** Interrupted by Incoming Call ****`r`n`r`n"
  126.                         statmsg "Mailrun interrupted by incoming call"
  127.                         capture OFF
  128.                         exit
  129.                     endif
  130.                 endwhile
  131.             else
  132.                 FirstCall = 0
  133.             endif
  134.             ;Dial the BBS
  135.             strfmt ComString "ATDT%s`r" PhoneNum
  136.             strlen ComString ComStringLength
  137.             computs ComString ComStringLength
  138.             ;rxdata must be on in order to get characters from the modem
  139.             ComString = ""
  140.             ComMsg = ""
  141.             profilerd MailRun "MailRun" "DialTimeOut" DialOutTime
  142.             while (!$CARRIER) && (DialOutTime > 0)
  143.                 ;Loop until a connection is made, timeout is reached, or a
  144.                 ;negative connect message is received
  145.                 ComStringLength = $RXCOUNT
  146.                 comgets ComString ComStringLength
  147.                 if strfind ComString CnctFail1
  148.                     ComMsg = CnctFail1
  149.                     exitwhile
  150.                 elseif strfind ComString CnctFail2
  151.                     ComMsg = CnctFail2
  152.                     exitwhile
  153.                 elseif strfind ComString CnctFail3
  154.                     ComMsg = CnctFail3
  155.                     exitwhile
  156.                 elseif strfind ComString CnctFail4
  157.                     ComMsg = CnctFail4
  158.                     exitwhile
  159.                 elseif strfind ComString CnctFail5
  160.                     ComMsg = CnctFail5
  161.                     exitwhile
  162.                 endif
  163.                 rxflush
  164.                 statmsg "Dialing %s      %s     Waiting %d" \
  165.                     PhoneNum BBSName DialOutTime
  166.                 pause 1
  167.                 DialOutTime--
  168.             endwhile
  169.             set aspect rxdata OFF
  170.             if DialOutTime == 0
  171.                 ;If dial timed out...
  172.                 hangup
  173.                 ComMsg = "TIMEOUT"
  174.             endif
  175.             if $CARRIER
  176.                 ;if connected to a BBS...
  177.                 statmsg "Connected to %s" BBSName
  178.                 dobbs(i)
  179.                 makequeue()
  180.                 statmsg ""
  181.                 FirstCall = 1
  182.                 n--
  183.             endif
  184.             n++
  185.             DialString = getdialstring(&n)
  186.         endwhile
  187.         Attempts++
  188.     endwhile
  189.     capture OFF
  190.     statmsg ""
  191. endproc
  192.  
  193.  
  194. #comment
  195. *********************************************************************
  196. * 
  197. * DOBBS()
  198. * 
  199. * Called by main()
  200. * 
  201. * Calls readitem(), writeitem(), sendscript(), logoff(), fileexit()
  202. * maketasklist(), gettaskstring(), getcommandprompt(),
  203. * getmail(), sendmail(), dlfile(), ulfile(), sendcommand(),
  204. * 
  205. * Dispatches pending tasks for the BBS to which MailRun
  206. * is connected.
  207. * 
  208. *********************************************************************
  209. #endcomment
  210.  
  211. proc dobbs
  212. intparm i
  213. string Pending, TaskType, BBSName, BBSType
  214. integer FailCode
  215. integer j
  216.     ;Return to this point with a FailCode of 1 if carrier
  217.     ;is lost or the BBS times out
  218.     Failcode = 0
  219.     setjmp ErrorFail FailCode
  220.     if FailCode == 0
  221.         profilerd MailRun BBS "BBSType" BBSType
  222.         profilerd MailRun BBS "BBSName" BBSName
  223.         profilerd MailRun "MailRun" "IdleTimeout" IdleTimeout
  224.         ;Assume login to Conference 0
  225.         CurrentConf = "0"
  226.         Conf = "0"
  227.         strfmt TaskItem "%s`t`t`t%d`t%d" BBSName i 0
  228.         ;Highlight the current BBS in the task list
  229.         updatedlg 16
  230.  
  231.         ;The first item must be read before the first holding()
  232.         ;(which occurs in getcommandprompt()) in case an error occurs.
  233.         j = 1
  234.         Item = readitem(j)
  235.         getcommandprompt()
  236.         while not NULLSTR Item
  237.             ;Loop through each Item for this BBS
  238.             TaskItem = gettaskstring(i, j)
  239.             updatedlg 16
  240.             strextract Pending Item "," 0
  241.             if strcmpi Pending "1"
  242.                 ;If the item is pending, execute it
  243.                 strextract TaskType Item "," 2
  244.                 switch TaskType
  245.                     case "GetMail"
  246.                         statmsg "Getting Mail Packet"
  247.                         getmail()
  248.                     endcase
  249.                     case "SendMail"
  250.                         statmsg "Sending Reply Packet"
  251.                         sendmail()
  252.                     endcase
  253.                     case "GetFile"
  254.                         statmsg "Downloading File"
  255.                         dlfile()
  256.                     endcase
  257.                     case "SendFile"
  258.                         statmsg "Uploading File"
  259.                         ulfile()
  260.                     endcase
  261.                     case "SendCommand"
  262.                         statmsg "Sending Command"
  263.                         sendcommand()
  264.                     endcase
  265.                     case "SendScript"
  266.                         statmsg "Executing Script"
  267.                         sendscript()
  268.                     endcase
  269.                 endswitch
  270.                 ;Update the task list
  271.                 writeitem(j, Item)
  272.                 maketasklist()
  273.                 TaskItem = gettaskstring(i, j)
  274.                 ;Highlight the last completed item
  275.                 updatedlg 80
  276.             endif
  277.             j++
  278.             Item = readitem(j)
  279.         endwhile
  280.         getcommandprompt()
  281.     else
  282.         ;If timeout or loss of carrier
  283.         ;Change unfinished items to errors
  284.         while not NULLSTR Item
  285.             strextract Pending Item "," 0
  286.             if strcmpi Pending "1"
  287.                 strupdt Item "2" 0 1
  288.                 writeitem(j, Item)
  289.             endif
  290.             j++
  291.             Item = readitem(j)
  292.         endwhile
  293.         maketasklist()
  294.         j--
  295.         Item = readitem(j)
  296.         TaskItem = gettaskstring(i, j)
  297.         updatedlg 80
  298.     endif
  299.     statmsg "Logging off"
  300.     logoff()
  301.     if $CARRIER
  302.         ;If still connected after logoff...
  303.         errormsg "Unable to drop carrier; aborting..."
  304.         ;abort the mailrun
  305.         fileexit()
  306.     endif
  307. endproc
  308.  
  309.  
  310. #comment
  311. *********************************************************************
  312. * 
  313. * MAKEQUEUE()
  314. * 
  315. * Called by main(), parsedialog()
  316. * 
  317. * Calls openfile(), readbbs(), checkpending(),
  318. * interfaceon(), interfaceoff(), makefullname()
  319. * 
  320. * Creates a file of phone numbers for BBSs that have
  321. * pending items in the current mailrun.
  322. * 
  323. *********************************************************************
  324. #endcomment
  325.  
  326. proc makequeue
  327. string Pending, PhoneNum, Number_X, QueueList
  328. integer i, j
  329.     interfaceoff()
  330.     QueueList = makefullname(TempDir, "QUEUE.TMP")
  331.     openfile(QueueListFile, QueueList, _CREATE, _NORMAL)
  332.     i = 1
  333.     BBS = readbbs(i)
  334.     ;Loop through each BBS
  335.     while not NULLSTR BBS
  336.         pending = checkpending()
  337.         if strcmpi Pending "1"
  338.             ;If the BBS has pending items...
  339.             j = 1
  340.             strfmt Number_X "Number_%d" j
  341.             profilerd MailRun BBS Number_X PhoneNum
  342.             ;Loop through each phone number
  343.             while not NULLSTR PhoneNum
  344.                 fstrfmt QueueListFile "%s`t%d`r`n" PhoneNum i
  345.                 j++
  346.                 strfmt Number_X "Number_%d" j
  347.                 profilerd MailRun BBS Number_X PhoneNum
  348.             endwhile
  349.         endif
  350.         i++
  351.         BBS = readbbs(i)
  352.     endwhile
  353.     fclose QueueListFile
  354.     interfaceon()
  355. endproc
  356.  
  357.  
  358. #comment
  359. *********************************************************************
  360. * 
  361. * GETDIALSTRING()
  362. * 
  363. * Called by main()
  364. * 
  365. * Calls makefullname(), interfaceon(), interfaceoff(),
  366. * openfile()
  367. * 
  368. * Gets a DialString from the queue.  The string contains
  369. * a phone number and a bbs coordinate.
  370. * 
  371. *********************************************************************
  372. #endcomment
  373.  
  374. func getdialstring : string
  375. intparm n
  376. integer i
  377. string DialString, QueueList
  378.     interfaceoff()
  379.     DialString = ""
  380.     QueueList = makefullname(TempDir, "QUEUE.TMP")
  381.     openfile(QueueListFile, QueueList, _READWRITE, _TEXT)
  382.     i = 1
  383.     while i <= n
  384.         fgets QueueListFile DialString
  385.         if NULLSTR DialString
  386.             n = 0
  387.             exitwhile
  388.         endif
  389.         i++
  390.     endwhile
  391.     fclose QueueListFile
  392.     interfaceon()
  393.     return DialString
  394. endfunc
  395.  
  396.  
  397. #comment
  398. *********************************************************************
  399. * 
  400. * GETCOMMANDPROMPT()
  401. * 
  402. * Called by dobbs(), getconfprompt(), getotherprompt(),
  403. * ulfile(), dlfile(), sendcommand(), sendscript()
  404. * 
  405. * Calls holding(), checkcommandprompt()
  406. * 
  407. * Responds to prompts until the "Command" prompt is received.
  408. * 
  409. *********************************************************************
  410. #endcomment
  411.  
  412. proc getcommandprompt
  413.     when quiet 1 call checkcommandprompt
  414.     holding()
  415.     clearwhen quiet
  416. endproc
  417.  
  418.  
  419. #comment
  420. *********************************************************************
  421. * 
  422. * CHECKCOMMANDPROMPT()
  423. * 
  424. * Called by getcommandprompt()
  425. * 
  426. * Calls checkbaseset(), findstring(), endhold()
  427. * 
  428. * Checks the prompt and sends the appropriate response.
  429. * 
  430. *********************************************************************
  431. #endcomment
  432.  
  433. proc checkcommandprompt
  434. string NamePrompt, UserName, BBSType
  435. string PWordPrompt, PWord, FilePrompt
  436. string MailPrompt, CommandPrompt, MsgMenuPrompt
  437.     profilerd MailRun BBS "BBSType" BBSType
  438.     profilerd MailRun BBS "NamePrompt" NamePrompt
  439.     profilerd MailRun BBS "PWordPrompt" PWordPrompt
  440.     profilerd MailRun BBS "FilePrompt" FilePrompt
  441.     profilerd MailRun BBS "MailPrompt" MailPrompt
  442.     profilerd MailRun BBS "CommandPrompt" CommandPrompt
  443.     profilerd MailRun BBS "MsgMenuPrompt" MsgMenuPrompt
  444.     if !(checkbaseset())
  445.         if findstring(prompt, MailPrompt) || \
  446.             (findstring(BBSType, "WildCat") && \
  447.             findstring(prompt, MsgMenuPrompt))
  448.             transmit "q^M"
  449.         elseif findstring(BBSType, "WildCat") && \
  450.             findstring(prompt, "Join conference")
  451.             transmit Conf
  452.             transmit "^M"
  453.         elseif findstring(prompt, NamePrompt)
  454.             profilerd MailRun BBS "UserName" UserName
  455.             transmit UserName
  456.             transmit "^M"
  457.         elseif findstring(prompt, PWordPrompt)
  458.             profilerd MailRun BBS "PWord" PWord
  459.             transmit PWord
  460.             transmit "^M"
  461.         elseif findstring(prompt, "Escape") || findstring(prompt, " ESC ")
  462.             ;send escape character
  463.             computc 0x1B
  464.           if findstring(prompt, "twice") || findstring(prompt, "two")
  465.                 ;pause 50 milliseconds
  466.                 mspause 50
  467.                 computc 0x1B
  468.             endif
  469.         elseif findstring(prompt, CommandPrompt) || \
  470.             findstring(prompt, FilePrompt)
  471.             endhold()
  472.         endif
  473.     endif
  474. endproc
  475.  
  476.  
  477. #comment
  478. *********************************************************************
  479. * 
  480. * GETCONFPROMPT()
  481. * 
  482. * Called by ulfile(), dlfile()
  483. * 
  484. * Calls getcommandprompt(), findstring()
  485. * 
  486. * Changes conferences if necessary.
  487. * 
  488. *********************************************************************
  489. #endcomment
  490.  
  491. proc getconfprompt
  492. string BBSType
  493.     profilerd MailRun BBS "BBSType" BBSType
  494.     if not strcmpi CurrentConf Conf
  495.         ;If we have to change conferences...
  496.         if findstring(BBSType, "WildCat")
  497.             transmit "j^M"
  498.         elseif findstring(BBSType, "PCBoard")
  499.             transmit "j;"
  500.             transmit Conf
  501.             transmit "^M"
  502.         endif
  503.         getcommandprompt()
  504.         CurrentConf = Conf
  505.     endif
  506. endproc
  507.  
  508.  
  509. #comment
  510. *********************************************************************
  511. * 
  512. * CHECKMAILPROMPT()
  513. * 
  514. * Called by getmail(), sendmail()
  515. * 
  516. * Calls endhold(), findstring(), checkbaseset()
  517. * 
  518. * Opens the mail door and gets the mail prompt.
  519. * 
  520. *********************************************************************
  521. #endcomment
  522.  
  523. proc checkmailprompt
  524. string MailPrompt, CommandPrompt, MailDoor, FilePrompt
  525. string BBSType, MsgMenuPrompt
  526.     profilerd MailRun BBS "BBSType" BBSType
  527.     profilerd MailRun BBS "MsgMenuPrompt" MsgMenuPrompt
  528.     profilerd MailRun BBS "MailPrompt" MailPrompt
  529.     profilerd MailRun BBS "CommandPrompt" CommandPrompt
  530.     profilerd MailRun BBS "FilePrompt" FilePrompt
  531.     if !(checkbaseset())
  532.         if findstring(BBSType, "WildCat") && \
  533.             (findstring(prompt, CommandPrompt) || findstring(prompt, FilePrompt))
  534.             transmit "M^M"
  535.         elseif findstring(prompt, MailPrompt)
  536.             endhold()
  537.         elseif (findstring(prompt, CommandPrompt) && \
  538.             (findstring(BBSType, "PCBoard") || findstring(BBSType, "RBBS"))) || \
  539.             (findstring(BBSType, "WildCat") && findstring(prompt, MsgMenuPrompt))
  540.             profilerd MailRun BBS "MailDoor" MailDoor
  541.             transmit MailDoor
  542.             transmit "^M"
  543.         endif
  544.     endif
  545. endproc
  546.  
  547.  
  548. #comment
  549. *********************************************************************
  550. * 
  551. * CHECKDESCPROMPT()
  552. * 
  553. * Called by ulfile(), dlfile()
  554. * 
  555. * Calls findstring(), endhold(), checkbaseset()
  556. * 
  557. * Checks for presense of the upload description prompt.
  558. * Sets promptstatus to 0 if the file already on the board.
  559. * 
  560. *********************************************************************
  561. #endcomment
  562.  
  563. proc checkdescprompt
  564. string ULDescPrompt, DLUnavPrompt, CommandPrompt, FilePrompt, BBSType
  565.     profilerd MailRun BBS "BBSType" BBSType
  566.     profilerd MailRun BBS "ULDescPrompt" ULDescPrompt
  567.     profilerd MailRun BBS "DLUnavPrompt" DLUnavPrompt
  568.     profilerd MailRun BBS "CommandPrompt" CommandPrompt
  569.     profilerd MailRun BBS "FilePrompt" FilePrompt
  570.     if !(checkbaseset())
  571.         if findstring(prompt, "file # 2") || findstring(prompt, "file #2") || \
  572.             findstring(prompt, "Keywords? [")
  573.             transmit "^M"
  574.         elseif (findstring(BBSType, "WildCat") && \
  575.             (findstring(prompt, "password protect") || \
  576.             findstring(prompt, "detailed") || \
  577.             findstring(prompt, "last download"))) || \
  578.             (findstring(BBSType, "RBBS") && \
  579.             findstring(prompt, "Extended description"))
  580.             transmit "n^M"
  581.         elseif findstring(prompt, "after upload")
  582.             transmit "c^M"
  583.         elseif findstring(BBSType, "RBBS") && findstring(prompt, "To A)ll")
  584.             transmit "a^M"
  585.             foundstatus = 1
  586.             endhold()
  587.         elseif findstring(prompt, ULDescPrompt)
  588.             foundstatus = 1
  589.             endhold()
  590.         elseif findstring(prompt, DLUnavPrompt) || \
  591.             findstring(prompt, "file # 1") || findstring(prompt, "file #1") || \
  592.             findstring(prompt, CommandPrompt) || findstring(prompt, FilePrompt)
  593.             if findstring(BBSType, "Auntie") && !(findstring(prompt, FilePrompt))
  594.                 transmit "q^M"
  595.             endif
  596.             foundstatus = 0
  597.             endhold()
  598.         endif
  599.     endif
  600. endproc
  601.  
  602.  
  603. #comment
  604. *********************************************************************
  605. * 
  606. * GOTULDLPROMPT()
  607. * 
  608. * Called by ulfile()
  609. * 
  610. * Releases the hold when the upload prompt is received.
  611. * 
  612. *********************************************************************
  613. #endcomment
  614.  
  615. proc gotuldlprompt
  616.     foundstatus = 1
  617.     endhold()
  618. endproc
  619.  
  620.  
  621. #comment
  622. *********************************************************************
  623. * 
  624. * GETOTHERPROMPT()
  625. * 
  626. * Called by sendmail(), getmail(), ulfile(), dlfile(),
  627. * sendcommand(), sendscript()
  628. * 
  629. * Calls findstring(), getcommandprompt()
  630. * 
  631. * For BBSs with a separate File prompt, moves to or from
  632. * the prompt.
  633. * 
  634. *********************************************************************
  635. #endcomment
  636.  
  637. proc getotherprompt
  638. intparm gotoplace
  639. string FilePrompt, BBSType
  640.     profilerd MailRun BBS "BBSType" BBSType
  641.     profilerd MailRun BBS "FilePrompt" FilePrompt
  642.     if !(findstring(prompt, FilePrompt)) && (gotoplace == GOTOFILE)
  643.         transmit "f^M"
  644.     elseif findstring(prompt, FilePrompt) && (gotoplace == GOTOMAIN)
  645.         transmit "q"
  646.         if findstring(BBSType, "RBBS")
  647.             transmit ";m"
  648.         endif
  649.         transmit "^M"
  650.     endif
  651.     getcommandprompt()
  652. endproc
  653.  
  654.  
  655. #comment
  656. *********************************************************************
  657. * 
  658. * CHECKBASESET()
  659. * 
  660. * Called by checkcommandprompt(), checkmailprompt(),
  661. * checkdescprompt()
  662. * 
  663. * Calls findstring()
  664. * 
  665. * Checks the base set of prompts.  Returns 1 if a prompt
  666. * was found; otherwise returns 0.
  667. * 
  668. *********************************************************************
  669. #endcomment
  670.  
  671. func checkbaseset : integer
  672. string LangPrompt, LangNumber, GraphicsPrompt, ScanPrompt
  673. string MorePrompt, ViewPrompt, CallingFrom, UserResp1, UserResp2
  674. string ContinuePrompt, UserPrompt1, UserPrompt2, BBSType
  675.     profilerd MailRun BBS "BBSType" BBSType
  676.     profilerd MailRun BBS "CallingFrom" CallingFrom
  677.     profilerd MailRun BBS "UserPrompt1" UserPrompt1
  678.     profilerd MailRun BBS "UserPrompt2" UserPrompt2
  679.     profilerd MailRun BBS "UserResp1" UserResp1
  680.     profilerd MailRun BBS "UserResp2" UserResp2
  681.     profilerd MailRun BBS "ContinuePrompt" ContinuePrompt
  682.     profilerd MailRun BBS "ScanPrompt" ScanPrompt
  683.     profilerd MailRun BBS "MorePrompt" MorePrompt
  684.     profilerd MailRun BBS "ViewPrompt" ViewPrompt
  685.     profilerd MailRun BBS "LangPrompt" LangPrompt
  686.     profilerd MailRun BBS "GraphicsPrompt" GraphicsPrompt
  687.     if findstring(prompt, UserPrompt1)
  688.         transmit UserResp1
  689.         transmit "^M"
  690.     elseif findstring(prompt, UserPrompt2)
  691.         transmit UserResp2
  692.         transmit "^M"
  693.     elseif findstring(prompt, ScanPrompt) || \
  694.         (findstring(prompt, MorePrompt) && !(findstring(BBSType, "WildCat")))
  695.         transmit "n^M"
  696.     elseif findstring(prompt, MorePrompt) && \
  697.         findstring(BBSType, "WildCat")
  698.         transmit "s^M"
  699.     elseif (findstring(prompt, ContinuePrompt) && \
  700.         findstring(BBSType, "PCBoard")) || \
  701.         findstring(prompt, CallingFrom)
  702.         transmit "y^M"
  703.     elseif findstring(prompt, ContinuePrompt) && \
  704.         !(findstring(BBSType, "PCBoard"))
  705.         transmit "^M"
  706.     elseif findstring(prompt, ViewPrompt)
  707.         if findstring(BBSType, "PCBoard") || findstring(BBSType, "WildCat")
  708.             transmit "n"
  709.         elseif findstring(BBSType, "RBBS")
  710.             transmit "q"
  711.         endif
  712.         transmit "^M"
  713.     elseif findstring(prompt, LangPrompt)
  714.         profilerd MailRun BBS "LangNumber" LangNumber
  715.         transmit LangNumber
  716.         transmit "^M"
  717.     elseif findstring(prompt, GraphicsPrompt)
  718.         profilerd MailRun BBS "GraphicsOn" GraphicsOn
  719.         if GraphicsOn == 0
  720.             transmit "n^M"
  721.         else
  722.             transmit "y^M"
  723.         endif
  724.     else
  725.         return 0
  726.     endif
  727.     return 1
  728. endfunc
  729.  
  730.  
  731. #comment
  732. *********************************************************************
  733. * 
  734. * HOLDING()
  735. * 
  736. * Called by getcommandprompt(), sendmail(), getmail(),
  737. * ulfile(), dlfile(), sendcommand()
  738. *
  739. * Calls capturescreen()
  740. * 
  741. * Jumps to ErrorFail in dobbs()
  742. * 
  743. * Stalls script while waiting for the result of a when
  744. * command.  Sends script to next BBS if there is a
  745. * timeout, or if carrier is lost.
  746. * 
  747. *********************************************************************
  748. #endcomment
  749.  
  750. proc holding
  751. string LastPrompt
  752.     IdleTimer = 1
  753.     holdstatus = 1
  754.     prompt = ""
  755.     xferstatus = $FILEXFER
  756.     while (IdleTimer < IdleTimeout) && (holdstatus == 1) && \
  757.         (xferstatus == 0) && $CARRIER
  758.         pause 1
  759.         termgets $ROW 0 prompt 79
  760.         if not strcmp prompt LastPrompt
  761.             ;if anything has been received, reset the timer
  762.             IdleTimer = 1
  763.         endif
  764.         LastPrompt = prompt
  765.         if !(IdleTimer % 15)
  766.             ;Send a carriage return every 15 seconds
  767.             transmit "^M"
  768.         endif
  769.         IdleTimer++
  770.         xferstatus = $FILEXFER
  771.     endwhile
  772.     if (IdleTimer == IdleTimeout) || ($CARRIER == 0)
  773.         ;If there has been a timeout, lost carrier or user escape...
  774.         clearwhen quiet
  775.         ;set FailCode and get out
  776.         capturescreen()
  777.         if IdleTimer == IdleTimeout
  778.             capturestr "`r`n`r`n*** Timed out waiting for prompt ***`r`n`r`n"
  779.         else
  780.             capturestr "`r`n`r`n*********** Lost carrier ***********`r`n`r`n"
  781.         endif
  782.         longjmp ErrorFail 1
  783.     endif
  784. endproc
  785.  
  786.  
  787. #comment
  788. *********************************************************************
  789. * 
  790. * ENDHOLD()
  791. * 
  792. * Releases a hold placed by holding()
  793. * 
  794. *********************************************************************
  795. #endcomment
  796.  
  797. proc endhold
  798.     holdstatus = 0
  799. endproc
  800.  
  801.  
  802. #comment
  803. *********************************************************************
  804. * 
  805. * WAITXFER()
  806. * 
  807. * Called by sendmail(), getmail(), ulfile(), dlfile()
  808. * 
  809. * Stalls script until a file transfer has been completed.
  810. * 
  811. *********************************************************************
  812. #endcomment
  813.  
  814. proc waitxfer
  815.     xferstatus = $FILEXFER
  816.     while xferstatus == 1
  817.         xferstatus = $FILEXFER
  818.     endwhile
  819. endproc
  820.  
  821.  
  822. #comment
  823. *********************************************************************
  824. * 
  825. * SENDMAIL()
  826. * 
  827. * Called by dobbs()
  828. * 
  829. * Calls checkmailprompt(), holding(), waitxfer(),
  830. * findstring(), makefullname(), getotherprompt(),
  831. * capturescreen()
  832. * 
  833. * Uploads a *.REP packet for the current BBS.
  834. * 
  835. *********************************************************************
  836. #endcomment
  837.  
  838. proc sendmail
  839. string MailULPrompt, MailXferProt, BBSType
  840. string ReplyFile, ReplyDir
  841. string Pending, temp
  842. integer j
  843.     profilerd MailRun BBS "BBSType" BBSType
  844.     profilerd MailRun "MailRun" "ReplyDir" ReplyDir
  845.     ReplyFile = makefullname(ReplyDir, BBS)
  846.     strcat ReplyFile ".REP"
  847.     if isfile ReplyFile
  848.         ;If there is a REP packet waiting...
  849.         if findstring(BBSType, "Auntie") || findstring(BBSType, "RBBS")
  850.             getotherprompt(GOTOMAIN)
  851.         endif
  852.         if findstring(BBSType, "Auntie")
  853.             transmit "QMU^M"
  854.         else
  855.             when quiet 1 call checkmailprompt
  856.             holding()
  857.             clearwhen quiet
  858.             transmit "u^M"
  859.         endif
  860.         profilerd MailRun BBS "MailULPrompt" MailULPrompt
  861.         when target 0 MailULPrompt call endhold
  862.         holding()
  863.         clearwhen target 0
  864.         set upldpath ReplyDir
  865.         profilerd MailRun BBS "MailXferProt" MailXferProt
  866.         sendfile MailXferProt ReplyFile
  867.         ;Hold until the transfer starts
  868.         holding()
  869.         ;Hold until the transfer finishes
  870.         waitxfer()
  871.         if xferstatus == 2
  872.             ;If upload was successful...
  873.             ;Rename the .REP packet as *.OLD
  874.             temp = ReplyFile
  875.             strlen temp j
  876.             j -= 3
  877.             strupdt temp "OLD" j 3
  878.             delfile temp
  879.             rename ReplyFile temp
  880.             ;Mark the Item as completed
  881.             Pending = "0"
  882.         else
  883.             ;Otherwise, mark it as an error
  884.             Pending = "2"
  885.             capturescreen()
  886.             capturestr "`r`n`r`n******* Error in File Transfer *******`r`n`r`n"
  887.         endif
  888.     else
  889.         Pending = "0"
  890.     endif
  891.     ;Update the *.MRN file
  892.     strupdt Item Pending 0 1
  893. endproc
  894.  
  895.  
  896. #comment
  897. *********************************************************************
  898. * 
  899. * GETMAIL()
  900. * 
  901. * Called by dobbs()
  902. * 
  903. * Calls checkmailprompt(), holding(), waitxfer, cleardir(),
  904. * renameqwk(), checkmail(), findstring(), makefullname(),
  905. * getotherprompt(), capturescreen()
  906. * 
  907. * Downloads a *.QWK packet for the current BBS.
  908. * 
  909. *********************************************************************
  910. #endcomment
  911.  
  912. proc getmail
  913. string MailFile, MailDLDir, MailDLPrompt, MailXferProt, CommandPrompt
  914. string Pending, temp, BBSType
  915.     profilerd MailRun BBS "BBSType" BBSType
  916.     foundstatus = 1
  917.     if findstring(BBSType, "Auntie") || findstring(BBSType, "RBBS") 
  918.         getotherprompt(GOTOMAIN)
  919.     endif
  920.     if findstring(BBSType, "Auntie")
  921.         transmit "QMD^M"
  922.     else
  923.         when quiet 1 call checkmailprompt
  924.         holding()
  925.         clearwhen quiet
  926.         transmit "d^M"
  927.         ;Wait for a prompt indicated presense of mail
  928.         when quiet 1 call checkmail
  929.         holding()
  930.         clearwhen quiet
  931.         if foundstatus == 0
  932.             Pending = "0"
  933.             strupdt Item Pending 0 1
  934.             return
  935.         endif
  936.         ;If there is mail...
  937.         transmit "y^M"
  938.     endif
  939.     ;Wait until asked to start the download
  940.     profilerd MailRun BBS "MailDLPrompt" MailDLPrompt
  941.     profilerd MailRun BBS "CommandPrompt" CommandPrompt
  942.     when target 0 MailDLPrompt call endhold
  943.     when target 1 CommandPrompt call killmaildl
  944.     holding()
  945.     clearwhen target 0
  946.     clearwhen target 1
  947.     ;If the command prompt has put in an appearance, abort the d/l
  948.     if foundstatus == 0
  949.         Pending = "0"
  950.         strupdt Item Pending 0 1
  951.         return
  952.     endif
  953.     ;Download to the mail download directory
  954.     MailDLDir = makefullname(MailRunDir, "MAILDL")
  955.     mkdir MailDLDir
  956.     cleardir(MailDLDir)
  957.     set dnldpath MailDLDir
  958.     strfmt temp "%s.QWK" BBS
  959.     profilerd MailRun BBS "MailXferProt" MailXferProt
  960.     getfile MailXferProt temp
  961.     ;Hold until the transfer starts
  962.     holding()
  963.     ;Hold until the transfer finishes
  964.     waitxfer()
  965.     if xferstatus == 2
  966.         ;If the download was successful...
  967.         ;Make sure the mail file has the ".QWK" extension.
  968.             ;This complicated workaround is the only way I could
  969.         ;figure out how to get the filename of a file that has
  970.         ;just been downloaded.
  971.         temp = makefullname(MailDLDir, "*.*")
  972.         findfirst temp
  973.         temp = makefullname(MailDLDir, $FILENAME)
  974.         MailFile = makefullname(MailDLDir, BBS)
  975.         strcat MailFile ".QWK"
  976.         rename temp MailFile
  977.         ;Renumber the QWK packets
  978.         renameqwk(MailFile)
  979.         ;and mark it as completed
  980.         Pending = "0"
  981.     else
  982.         ;Otherwise, mark the item as an error
  983.         Pending = "2"
  984.         capturescreen()
  985.         capturestr "`r`n`r`n***** Error in File Transfer *****`r`n`r`n"
  986.     endif
  987.     ;Delete the mail download directory
  988.     cleardir(MailDLDir)
  989.     chdir MailRunDir
  990.     rmdir MailDLDir
  991.     strupdt Item Pending 0 1
  992. endproc
  993.  
  994.  
  995. #comment
  996. *********************************************************************
  997. * 
  998. * CHECKMAIL()
  999. * 
  1000. * Called by getmail()
  1001. * 
  1002. * Calls findstring(), endhold()
  1003. * 
  1004. * Checks prompt for presense of a mail packet.
  1005. * 
  1006. *********************************************************************
  1007. #endcomment
  1008.  
  1009. proc checkmail
  1010. string ReceiveQWKPrompt, MailPrompt
  1011.     profilerd MailRun BBS "ReceiveQWKPrompt" ReceiveQWKPrompt
  1012.     profilerd MailRun BBS "MailPrompt" MailPrompt
  1013.     if findstring(prompt, MailPrompt)
  1014.         foundstatus = 0
  1015.         endhold()
  1016.     elseif findstring(prompt, ReceiveQWKPrompt)
  1017.         endhold()
  1018.     endif
  1019. endproc
  1020.  
  1021.  
  1022. #comment
  1023. *********************************************************************
  1024. * 
  1025. * KILLMAILDL()
  1026. * 
  1027. * Called by getmail()
  1028. * 
  1029. * If there is no mail packet, kills attempt to d/l.
  1030. * 
  1031. *********************************************************************
  1032. #endcomment
  1033.  
  1034. proc killmaildl
  1035.     foundstatus = 0
  1036.     endhold()
  1037. endproc
  1038.  
  1039.  
  1040. #comment
  1041. *********************************************************************
  1042. * 
  1043. * RENAMEQWK()
  1044. * 
  1045. * Called by getmail()
  1046. * 
  1047. * Calls makefullname()
  1048. * 
  1049. * Renames QWK packets after a successful mail download.
  1050. * 
  1051. *********************************************************************
  1052. #endcomment
  1053.  
  1054. proc renameqwk
  1055. strparm MailFile
  1056. string OldMail1, OldMail2, MailDir
  1057. string char
  1058. integer i, j
  1059.     profilerd MailRun "MailRun" "MailDir" MailDir
  1060.     OldMail2 = makefullname(MailDir, BBS)
  1061.     profilerd MailRun "MailRun" "SavePackets" i
  1062.     ;max of 10 packets
  1063.     if i > 10
  1064.         i = 10
  1065.     endif
  1066.     i -= 1
  1067.     if i > 0
  1068.         strfmt OldMail2 "%s.QW%d" OldMail2 i
  1069.     elseif i == 0
  1070.         strfmt OldMail2 "%s.QW0" OldMail2
  1071.     else
  1072.         strfmt OldMail2 "%s.QWK" OldMail2
  1073.     endif
  1074.     ;Delete oldest file
  1075.     delfile OldMail2
  1076.     OldMail1 = OldMail2
  1077.     strlen OldMail1 j
  1078.     j -= 1
  1079.     while i > 0
  1080.         i--
  1081.         itoa i char
  1082.         strupdt OldMail1 char j 1
  1083.         ;Rename the second oldest as the oldest
  1084.         rename OldMail1 OldMail2
  1085.         ;Rotate filenames
  1086.         OldMail2 = OldMail1
  1087.     endwhile
  1088.     if i == 0
  1089.         ;if the oldest is QW0...
  1090.         strupdt OldMail1 "K" j 1
  1091.         rename OldMail1 OldMail2
  1092.         OldMail2 = OldMail1
  1093.     endif
  1094.     delfile OldMail2
  1095.     copyfile MailFile OldMail1
  1096.     delfile MailFile
  1097. endproc
  1098.  
  1099.  
  1100. #comment
  1101. *********************************************************************
  1102. * 
  1103. * ULFILE()
  1104. * 
  1105. * Called by dobbs()
  1106. * 
  1107. * Calls getconfprompt(), getcommandprompt(), getotherprompt(),
  1108. * holding(), waitxfer(), checkdescprompt(), findstring(),
  1109. * checkverifyprompt(), gotuldlprompt(), senddesc(),
  1110. * capturescreen()
  1111. * 
  1112. * Uploads a file to the current BBS.
  1113. * 
  1114. *********************************************************************
  1115. #endcomment
  1116.  
  1117. proc ulfile
  1118. string Pending, ULPrompt, ULDescPrompt, UploadDir, XferProt
  1119. string FileName, BBSType
  1120.     profilerd MailRun BBS "BBSType" BBSType
  1121.     Pending = "2"
  1122.     strextract FileName Item "," 3
  1123.     strextract Conf item "," 4
  1124.     ;Change conferences if necessary
  1125.     getcommandprompt()
  1126.     if findstring(BBSType, "PCBoard") || findstring(BBSType, "WildCat")
  1127.         getconfprompt()
  1128.     endif
  1129.     if !(findstring(BBSType, "PCBoard"))
  1130.         getotherprompt(GOTOFILE)
  1131.     endif
  1132.     if findstring(BBSType, "WildCat")
  1133.         transmit "u^M"
  1134.         when quiet 1 call checkdescprompt
  1135.         holding()
  1136.         clearwhen quiet
  1137.     else
  1138.         transmit "u;"
  1139.     endif
  1140.     transmit FileName
  1141.     if findstring(BBSType, "Auntie")
  1142.         transmit ";n"
  1143.     endif
  1144.     transmit "^M"
  1145.     ;Check whether file is already on the board
  1146.     when quiet 1 call checkdescprompt
  1147.     holding()
  1148.     clearwhen quiet
  1149.     if foundstatus == 1
  1150.         if !(findstring(BBSType, "RBBS"))
  1151.             senddesc(FileName)
  1152.         endif
  1153.         if findstring(BBSType, "Auntie")
  1154.             when quiet 1 call checkverifyprompt
  1155.             holding()
  1156.             clearwhen quiet
  1157.         endif
  1158.         profilerd MailRun BBS "ULPrompt" ULPrompt
  1159.         when target 0 ULPrompt call gotuldlprompt
  1160.         when quiet 1 call checkdescprompt
  1161.         holding()
  1162.         clearwhen quiet
  1163.         clearwhen target 0
  1164.         xferstatus = 1
  1165.         profilerd MailRun "MailRun" "UploadDir" UploadDir
  1166.         set upldpath UploadDir
  1167.         profilerd MailRun BBS "XferProt" XferProt
  1168.         sendfile XferProt FileName
  1169.         ;Wait until the transfer starts
  1170.         holding()
  1171.         ;Wait until the transfer finishes
  1172.         waitxfer()
  1173.         if xferstatus == 2
  1174.             ;If the download was successful...
  1175.             if findstring(BBSType, "RBBS")
  1176.                 when quiet 1 call checkverifyprompt
  1177.                 holding()
  1178.                 clearwhen quiet
  1179.                 profilerd MailRun BBS "ULDescPrompt" ULDescPrompt
  1180.                 when target 0 ULDescPrompt call endhold
  1181.                 when quiet 1 call checkdescprompt
  1182.                 holding()
  1183.                 clearwhen quiet
  1184.                 clearwhen target 0
  1185.                 if foundstatus == 1
  1186.                     senddesc(FileName)
  1187.                     when quiet 1 call checkdescprompt
  1188.                     holding()
  1189.                     clearwhen quiet
  1190.                 endif
  1191.             endif
  1192.             ;Mark as completed
  1193.             Pending = "0"
  1194.         else
  1195.             ;Otherwise, mark as an error
  1196.             capturescreen()
  1197.             capturestr "`r`n`r`n***** Error in File Transfer *****`r`n`r`n"
  1198.         endif
  1199.     else
  1200.         ;If the file was already on the board
  1201.         ;Send a carriage return to get the prompt back
  1202.         transmit "^M"
  1203.         if findstring(BBSType, "WildCat")
  1204.             pause 1
  1205.             transmit "A^M"
  1206.         endif
  1207.     endif
  1208.     strupdt Item Pending 0 1
  1209. endproc
  1210.  
  1211.  
  1212. #comment
  1213. *********************************************************************
  1214. * 
  1215. * CHECKVERIFYPROMPT()
  1216. * 
  1217. * Called by ulfile()
  1218. * 
  1219. * Calls findstring(), endhold()
  1220. * 
  1221. * Checks for prompt to send the category or file area to
  1222. * which a file should be uploaded.
  1223. * 
  1224. *********************************************************************
  1225. #endcomment
  1226.  
  1227. proc checkverifyprompt
  1228. string BBSType
  1229.     profilerd MailRun BBS "BBSType" BBSType
  1230.     if findstring(BBSType, "Auntie") && findstring(prompt, "editor function")
  1231.         transmit "s^M"
  1232.     elseif findstring(prompt, "category")
  1233.         transmit Conf
  1234.         if findstring(BBSType, "Auntie")
  1235.             transmit ";y;n^M"
  1236.         endif
  1237.         endhold()
  1238.     endif
  1239. endproc
  1240.  
  1241.  
  1242. #comment
  1243. *********************************************************************
  1244. * 
  1245. * SENDDESC()
  1246. * 
  1247. * Called by ulfile()
  1248. * 
  1249. * Calls checkfile(), makefullname(), openfile(), interfaceon(),
  1250. * interfaceoff(), findstring()
  1251. * 
  1252. * Sends the file description of a file to be uploaded;
  1253. * otherwise sends "Description not available".
  1254. * 
  1255. *********************************************************************
  1256. #endcomment
  1257.  
  1258. proc senddesc
  1259. strparm FileName
  1260. string UDXString, UDXFile, MRunUDX, MRunUBF, BBSType
  1261. string DB, DL
  1262. integer char
  1263. long DescBegin, DescLength
  1264. long counter
  1265.     profilerd MailRun BBS "BBSType" BBSType
  1266.     MRunUDX = makefullname(MailRunDir, "MAILRUN.UDX")
  1267.     MRunUBF = makefullname(MailRunDir, "MAILRUN.UBF")
  1268.     ;If the file is not on the board, send a description
  1269.     if checkfile(MRunUDX) && checkfile(MRunUBF)
  1270.         interfaceoff()
  1271.         openfile(MRunUBFFile, MRunUBF, _READWRITE, _NORMAL)
  1272.         openfile(MRunUDXFile, MRunUDX, _READWRITE, _TEXT)
  1273.         fgets MRunUDXFile UDXString
  1274.         strextract UDXFile UDXString "`t" 0
  1275.         while not strcmpi UDXFile FileName
  1276.             fgets MRunUDXFile UDXString
  1277.             strextract UDXFile UDXString "`t" 0
  1278.         endwhile
  1279.         strextract DB UDXString "`t" 4
  1280.         strextract DL UDXString "`t" 5
  1281.         atol DB DescBegin
  1282.         atol DL DescLength
  1283.         if findstring(BBSType, "WildCat")
  1284.             if DescLength > 60
  1285.                 DescLength = 60
  1286.             endif
  1287.         endif
  1288.         if findstring(BBSType, "RBBS")
  1289.             if DescLength > 45
  1290.                 DescLength = 45
  1291.             endif
  1292.         endif
  1293.         fseek MRunUBFFile DescBegin 0
  1294.         for counter = 1 upto DescLength
  1295.             fgetc MRunUBFFile char
  1296.             computc char
  1297.         endfor
  1298.         fclose MRunUBFFile
  1299.         fclose MRunUDXFile
  1300.         interfaceon()
  1301.     else
  1302.         transmit "Description not available"
  1303.     endif
  1304.     transmit "^M"
  1305.     if findstring(BBSType, "PCBoard") || findstring(BBSType, "Auntie")
  1306.         transmit "^M"
  1307.     endif
  1308. endproc
  1309.  
  1310.  
  1311. #comment
  1312. *********************************************************************
  1313. * 
  1314. * DLFILE()
  1315. * 
  1316. * Called by dobbs()
  1317. * 
  1318. * Calls getconfprompt(), getcommandprompt(), getotherprompt(),
  1319. * holding(), waitxfer(), putdesc(), findstring(),
  1320. * checkdescprompt(), gotuldlprompt(), capturescreen()
  1321. * 
  1322. * Downloads a file from the current BBS.
  1323. * 
  1324. *********************************************************************
  1325. #endcomment
  1326.  
  1327. proc dlfile
  1328. string Pending, DLPrompt, DownloadDir, XferProt, FileName, BBSType
  1329.     profilerd MailRun BBS "BBSType" BBSType
  1330.     strextract FileName Item "," 3
  1331.     strextract Conf Item "," 4
  1332.     ;Change conferences if necessary
  1333.     getcommandprompt()
  1334.     if !(findstring(BBSType, "Auntie"))
  1335.         getconfprompt()
  1336.     endif
  1337.     if !(findstring(BBSType, "PCBoard"))
  1338.         getotherprompt(GOTOFILE)
  1339.     endif
  1340.     if findstring(BBSType, "WildCat")
  1341.         transmit "d^M"
  1342.         when quiet 1 call checkdescprompt
  1343.         holding()
  1344.         clearwhen quiet
  1345.     else
  1346.         transmit "d;"
  1347.     endif
  1348.     transmit FileName
  1349.     transmit "^M"
  1350.     ;Check whether file is available for d/l
  1351.     profilerd MailRun BBS "DLPrompt" DLPrompt
  1352.     when target 0 DLPrompt call gotuldlprompt
  1353.     when quiet 1 call checkdescprompt
  1354.     holding()
  1355.     clearwhen quiet
  1356.     clearwhen target 0
  1357.     if foundstatus == 1
  1358.         ;If it is available...
  1359.         profilerd MailRun "MailRun" "DownloadDir" DownloadDir
  1360.         set dnldpath DownloadDir
  1361.         profilerd MailRun BBS "XferProt" XferProt
  1362.         getfile XferProt FileName
  1363.         ;Wait until the transfer starts
  1364.         holding()
  1365.         ;Wait until the transfer finishes
  1366.         waitxfer()
  1367.         if xferstatus == 2
  1368.             ;If the download was successful...
  1369.             putdesc(FileName)
  1370.             ;Mark as completed
  1371.             Pending = "0"
  1372.         else
  1373.             ;Otherwise, mark as an error
  1374.             Pending = "2"
  1375.             capturescreen()
  1376.             capturestr "`r`n`r`n*** Error in File Transfer ***`r`n`r`n"
  1377.         endif
  1378.     else
  1379.         ;If file was unavailable, mark as error.
  1380.         Pending = "2"
  1381.         ;Send a return to get the prompt back.
  1382.         transmit "^M"
  1383.     endif
  1384.     strupdt Item Pending 0 1
  1385. endproc
  1386.  
  1387.  
  1388. #comment
  1389. *********************************************************************
  1390. * 
  1391. * PUTDESC()
  1392. * 
  1393. * Called by dlfile()
  1394. * 
  1395. * Calls openfile(), checkfile(), interfaceoff(), interfaceon(),
  1396. * makefullname()
  1397. * 
  1398. * Searches the BBSs .IDX file for a file description and
  1399. * copies the description from the .DBF file to the uplaod
  1400. * files database.  If no description is found, a line
  1401. * including the file name, size and date is put in the
  1402. * upload files index.
  1403. * 
  1404. *********************************************************************
  1405. #endcomment
  1406.  
  1407. proc putdesc
  1408. strparm FileName
  1409. string DB, DL, idxString, MRunUDX, MRunUBF, BBSidx, BBSdbf
  1410. string idxFile, idxDesc, FileDate, FullFileName, DownloadDir
  1411. integer inidx, char
  1412. long DescBegin, DescLength, counter, FileSize
  1413.     interfaceoff()
  1414.     ;Determine whether the BBS index and database files exist
  1415.     BBSidx = makefullname(MailRunDir, BBS)
  1416.     strfmt BBSdbf "%s.DBF" BBSidx
  1417.     strcat BBSidx ".IDX"
  1418.     inidx = 0
  1419.     if checkfile(BBSidx) && checkfile(BBSdbf)
  1420.         ;If both files exist...
  1421.         openfile(BBSidxFile, BBSidx, _READWRITE, _TEXT)
  1422.         fgets BBSidxFile idxString
  1423.         while not feof BBSidxFile
  1424.             ;Loop through the index file and stop if the file is found
  1425.             strextract idxFile idxString "`t" 0
  1426.             if strcmpi FileName idxFile
  1427.                 inidx = 1
  1428.                 exitwhile
  1429.             endif
  1430.             fgets BBSidxFile idxString
  1431.         endwhile
  1432.         fclose BBSidxFile
  1433.     endif
  1434.     strlwr FileName
  1435.     ;Get the file size and date
  1436.     profilerd MailRun "MailRun" "DownloadDir" DownloadDir
  1437.     FullFileName = makefullname(DownloadDir, FileName)
  1438.     getfsize FullFileName FileSize
  1439.     getfdate FullFileName FileDate
  1440.     ;Determine whether the upload index and database files exist
  1441.     MRunUDX = makefullname(MailRunDir, "MAILRUN.UDX")
  1442.     MRunUBF = makefullname(MailRunDir, "MAILRUN.UBF")
  1443.     if checkfile(MRunUBF) && checkfile(MRunUDX)
  1444.         ;If both files exist, open them
  1445.         openfile(MRunUBFFile, MRunUBF, _READWRITE, _NORMAL)
  1446.         openfile(MRunUDXFile, MRunUDX, _READWRITE, _NORMAL)
  1447.     else
  1448.         ;Otherwise, create them
  1449.         openfile(MRunUBFFile, MRunUBF, _CREATE, _NORMAL)
  1450.         openfile(MRunUDXFile, MRunUDX, _CREATE, _NORMAL)
  1451.     endif
  1452.     fseek MRunUDXFile 0 2
  1453.     if inidx == 1
  1454.         ;If the file was found in the BBS index...
  1455.         strextract idxDesc idxString "`t" 3
  1456.         ;Get the descriptions starting point and length...
  1457.         strextract DB idxString "`t" 4
  1458.         strextract DL idxString "`t" 5
  1459.         atol DB DescBegin
  1460.         atol DL DescLength
  1461.         openfile(BBSdbfFile, BBSdbf, _READWRITE, _NORMAL)
  1462.         fseek BBSdbfFile DescBegin 0
  1463.         fseek MRunUBFFile 0 2
  1464.         ftell MRunUBFFile DescBegin
  1465.         ;And copy each character of the description to the upload database
  1466.         for counter = 1 upto DescLength
  1467.             fgetc BBSdbfFile char
  1468.             fputc MRunUBFFile char
  1469.         endfor
  1470.         fclose BBSdbfFile
  1471.         ;Format the upload index entry
  1472.         fstrfmt MRunUDXFile "%s`t%ld`t%s`t%s`t%ld`t%ld`r`n" \
  1473.             FileName FileSize FileDate idxDesc DescBegin DescLength
  1474.     else
  1475.         ;If there was no entry in the BBS index...
  1476.         ;Format the upload index entry
  1477.         fstrfmt MRunUDXFile "%s`t%ld`t%s`t`t0`t0`r`n" FileName FileSize FileDate
  1478.     endif
  1479.     fclose MRunUBFFile
  1480.     fclose MRunUDXFile
  1481.     interfaceon()
  1482. endproc
  1483.  
  1484.  
  1485. #comment
  1486. *********************************************************************
  1487. * 
  1488. * SENDCOMMAND()
  1489. * 
  1490. * Called by dobbs()
  1491. * 
  1492. * Calls getcommandprompt(), getotherprompt(), holding(), 
  1493. * findstring()
  1494. * 
  1495. * Sends commands to the current BBS.  A command item may
  1496. * contain multiple command lines separated by a vertical
  1497. * bar.  The script will send these one at a time, waiting
  1498. * until the terminal has been quiet for 15 seconds before
  1499. * sending the next one.  The command must return the user
  1500. * to the Main Command Prompt, or be the last item for the
  1501. * BBS.
  1502. * 
  1503. *********************************************************************
  1504. #endcomment
  1505.  
  1506. proc sendcommand
  1507. string CommandLine, Command, BBSType
  1508. integer j
  1509.     getcommandprompt()
  1510.     profilerd MailRun BBS "BBSType" BBSType
  1511.     if !(findstring(BBSType, "PCBoard"))
  1512.         getotherprompt(GOTOMAIN)
  1513.     endif
  1514.     strextract Command Item "," 3
  1515.     j = 0
  1516.     strextract CommandLine Command "|" j
  1517.     while not NULLSTR CommandLine
  1518.         if j != 0
  1519.             when quiet 10 call endhold
  1520.             holding()
  1521.             clearwhen quiet
  1522.         endif
  1523.         transmit CommandLine
  1524.         transmit "^M"
  1525.         j++
  1526.         strextract CommandLine Command "|" j
  1527.     endwhile
  1528.     strupdt Item "0" 0 1
  1529. endproc
  1530.  
  1531.  
  1532. #comment
  1533. *********************************************************************
  1534. * 
  1535. * SENDSCRIPT()
  1536. * 
  1537. * Called by dobbs()
  1538. * 
  1539. * Calls getcommandprompt(), getotherprompt(), mailrunbox(),
  1540. * findstring(), makefullname()
  1541. * 
  1542. * Executes a script file.  The script must return to the
  1543. * Main Command Prompt, or be the last item for that BBS.
  1544. * 
  1545. *********************************************************************
  1546. #endcomment
  1547.  
  1548. proc sendscript
  1549. string ScriptName, BBSType
  1550.     getcommandprompt()
  1551.     profilerd MailRun BBS "BBSType" BBSType
  1552.     if !(findstring(BBSType, "PCBoard"))
  1553.         getotherprompt(GOTOMAIN)
  1554.     endif
  1555.     strextract ScriptName Item "," 3
  1556.     ScriptName = makefullname(MailRunDir, ScriptName)
  1557.     execute ScriptName
  1558.     strupdt Item "0" 0 1
  1559.     mailrunbox()
  1560. endproc
  1561.  
  1562.  
  1563. #comment
  1564. *********************************************************************
  1565. * 
  1566. * LOGOFF()
  1567. * 
  1568. * Called by dobbs()
  1569. * 
  1570. * Logs off the current BBS.
  1571. * 
  1572. *********************************************************************
  1573. #endcomment
  1574.  
  1575. proc logoff
  1576. integer i = 1
  1577.     if $CARRIER
  1578.         transmit "g^M"
  1579.     endif
  1580.     pause 5
  1581.     while $CARRIER && (i < 3)
  1582.         hangup
  1583.         pause 5
  1584.         i++
  1585.     endwhile
  1586. endproc
  1587.  
  1588.  
  1589. #comment
  1590. *********************************************************************
  1591. * 
  1592. * MAILRUNBOX()
  1593. * 
  1594. * Called by main(), sendscript()
  1595. * 
  1596. * Draws the main MailRun dialog box.
  1597. * 
  1598. *********************************************************************
  1599. #endcomment
  1600.  
  1601. proc mailrunbox
  1602. destroydlg
  1603. MainBoxTabs = "20,30,220,230,233,236,239,242"
  1604. HelpPage = 2
  1605. dialogbox 8 36 346 181 15 "MailRun" HELPID HelpPage
  1606.    groupbox 10 33 228 135 "Task List" shadow
  1607.    flistbox 15 52 218 102 TaskList MainBoxTabs single TaskItem
  1608.    text  15 153 49 8 left "# = permanent"
  1609.    text  76 153 49 8 left "ñ = temporary"
  1610.    text  140 153 33 8 left "! = error"
  1611.    text  182 153 53 8 left "@ = completed"
  1612.    groupbox 244 33 90 135 "Statistics" shadow
  1613.    text  248 55 62 8 right "BBSs in mailrun:"
  1614.    text  248 69 62 8 right "BBSs completed:"
  1615.    text  248 83 62 8 right "BBSs left to call:"
  1616.    text  248 97 62 8 right "Items in mailrun:"
  1617.    text  248 111 62 8 right "Items completed:"
  1618.    text  248 125 62 8 right "Item errors:"
  1619.    text  248 139 62 8 right "Items remaining:"
  1620.    text  248 153 62 8 right "Dialing Attempt:"
  1621.    vtext 314 55 16 9 left BBSTotal
  1622.    vtext 314 69 16 9 left BBSComplete
  1623.    vtext 314 83 16 9 left BBSRemaining
  1624.    vtext 314 97 16 9 left ItemTotal
  1625.    vtext 314 111 16 9 left ItemComplete
  1626.    vtext 314 125 16 9 left ItemError
  1627.    vtext 314 139 16 9 left ItemRemaining
  1628.    vtext 314 153 16 9 left AttemptNum
  1629.    text  102 14 74 8 right "The current mailrun is:"
  1630.    combobox 180 12 76 41 MailRunTrunc MailRunTrunc
  1631.    pushbutton 0 0 0 0 "          &t" normal default
  1632.    pushbutton 0 0 0 0 "          &u" normal
  1633.    pushbutton 0 0 0 0 "          &i" normal
  1634. enddialog
  1635. disable CTRL 170
  1636. endproc
  1637.  
  1638.  
  1639. #comment
  1640. *********************************************************************
  1641. * 
  1642. * CAPTURESCREEN()
  1643. * 
  1644. * Called by main(), holding(), sendmail(), getmail(),
  1645. * ulfile(), dlfile()
  1646. * 
  1647. * Puts the current screen in the capture file.  Normally, the
  1648. * contents of a terminal screen are not placed in the capture
  1649. * file until they scroll off.  If a capture string is placed in
  1650. * a capture file, it will appear before the last screenfull of
  1651. * data.  This procedure is necessary to ensure that a capture
  1652. * string appears after all data that has already been received
  1653. * from the remote.
  1654. * 
  1655. *********************************************************************
  1656. #endcomment
  1657.  
  1658. proc capturescreen
  1659. string RowString
  1660. integer Row, MaxRows, MaxCols
  1661.     fetch terminal rows MaxRows
  1662.     fetch terminal columns MaxCols
  1663.     for Row = 0 upto MaxRows
  1664.         termgets Row 0 RowString MaxCols
  1665.         capturestr RowString
  1666.         capturestr "`r`n"
  1667.     endfor
  1668.     termreset
  1669. endproc
  1670.         
  1671.